Option Explicit
Private Sub BtnConectar_Click()
    ' Se cambia el Titulo del Formulario
    Me.Caption = App.Comments & " [" & TxtNick.Text & "]"
    ' Se activa el Socket
    SocketUDP.Protocol = sckUDPProtocol
    SocketUDP.RemoteHost = "255.255.255.255"
    SocketUDP.RemotePort = 2345
    SocketUDP.Bind 2345
    ' Limpia la lista de usuarios y activa o desactiva los
    ' controles que se estan usando
    LstUser.Clear
    TxtNick.Enabled = False
    BtnConectar.Enabled = False
    BtnDesconectar.Enabled = True
    LstChat.Enabled = True
    LstUser.Enabled = True
    TxtChat.Enabled = True
    BtnEnviar.Enabled = True
    TxtChat.SetFocus
    DoEvents
    ' Se informa al resto de chats que hay un nuevo usuario
    SocketUDP.SendData "User" & TxtNick.Text
    DoEvents
End Sub
Private Sub BtnDesconectar_Click()
    ' Se pone el titulo por defecto
    Me.Caption = App.Comments
    ' Se envia un mensaje a todos los usuarios
    ' que se va desconectar el usuario X y se
    ' cierra el socket
    SocketUDP.SendData "DisC" & TxtNick.Text
    DoEvents
    SocketUDP.Close
    ' Activa o desactiva los controles que se estan usando
    TxtNick.Enabled = True
    BtnConectar.Enabled = True
    BtnDesconectar.Enabled = False
    LstChat.Enabled = False
    LstUser.Enabled = False
    TxtChat.Enabled = False
    BtnEnviar.Enabled = False
End Sub
Private Sub Form_Load()
    ' Carga el formulario y
    ' muestra el titulo por defecto
    Me.Caption = App.Comments
End Sub
Private Sub Form_Unload(Cancel As Integer)
    ' Si el socket esta conectado
    If SocketUDP.State <> sckClosed Then
        ' Se envia el mensaje de que va a cerrar el programa
        ' y se desactiva el socket
        SocketUDP.SendData "Quit" & TxtNick.Text
        EliminarUsuario TxtNick.Text
        DoEvents
        SocketUDP.Close
    End If
End Sub
Private Sub SocketUDP_DataArrival(ByVal bytesTotal As Long)
    ' Gestiona la recepción de datos
    Dim LineaDatos As String, Comando As String, Parametros As String
    ' Se carga el array
    SocketUDP.GetData LineaDatos, vbString
    Comando = UCase$(Left$(LineaDatos, 4))
    If Len(LineaDatos) > 4 Then Parametros = Mid$(LineaDatos, 5)
    Select Case Comando
    Case "MENS"
        ' Cuando llega un mensaje de otro usuario
        LstChat.AddItem Format(Now, "hh:nn:ss ") & Parametros
    Case "USER"
        ' Cuando un usuario se ha conectado
        LstChat.AddItem "Se ha conectado " & Parametros
        LstUser.AddItem Parametros
        If SocketUDP.RemoteHostIP <> SocketUDP.LocalIP Then
            SocketUDP.RemoteHost = SocketUDP.RemoteHostIP
            SocketUDP.SendData "Conc" & TxtNick.Text
        End If
    Case "CONC"
        ' Son las ordenes de los usuarios que ya estaban conectados
        LstUser.AddItem Parametros
    Case "QUIT"
        ' El usuario X ha cerrado la aplicación
        LstChat.AddItem Parametros & " ha cerrado la aplicación."
        EliminarUsuario Parametros
    Case "DISC"
        ' El usuario X se ha desconectado del Chat.
        LstChat.AddItem Parametros & " ha desconectado."
        EliminarUsuario Parametros
    Case Else
        Debug.Print "Desconocido: " & LineaDatos
    End Select
End Sub
Private Sub TxtChat_GotFocus()
    TxtChat.SelStart = 0
    TxtChat.SelLength = Len(TxtChat)
End Sub
Private Sub TxtChat_KeyPress(KeyAscii As Integer)
    ' Si detecta un "Enter" envia el mensaje
    If KeyAscii = 13 Then BtnEnviar_Click
End Sub
Private Sub BtnEnviar_Click()
    ' Se conecta con el resto de Chats
    SocketUDP.RemoteHost = "255.255.255.255"
    ' y envia la información del mensaje
    SocketUDP.SendData "Mens" & TxtNick.Text & "> " & TxtChat.Text
    DoEvents
    ' Limpia la caja de texto para el siguiente mensaje
    TxtChat.Text = ""
    TxtChat.SetFocus
End Sub
Private Sub TxtNick_Change()
    ' Si hay algo de contenido en el Nick se activa el botón
    ' conectar
    BtnConectar.Enabled = IIf(Len(TxtNick.Text) > 0, True, False)
End Sub
Sub EliminarUsuario(Usuario As String)
    ' Busca el usuario indicado y lo elimina de la lista
    Dim Ic As Integer
    For Ic = 0 To LstUser.ListCount - 1
        If LstUser.List(Ic) = Usuario Then
            LstUser.RemoveItem Ic
        End If
    Next Ic
End Sub